home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / GRAPHICS / RAYTRACING / POVRAY3 / POV301 / povray3 / povscn / level2 / pov / skyvase < prev    next >
Text File  |  1995-11-08  |  3KB  |  122 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File by Dan Farmer
  3. //
  4. // NOTE: This image has traditionally been used as the standard
  5. // benchmark file.  At the time of POV-Ray 1.0, this scene rendered
  6. // in about the same time as the average of all of the standard scene
  7. // files.  Be cautious of making changes that will unfairly affect
  8. // benchmarks.  Please log all changes to this file below.
  9. // ===============
  10. // Change history
  11. // ===============
  12. // POV-Ray 3.0 changes:
  13. // DMF 1995 - Commented out bounding object.
  14. // DMF 1995 - Added max_trace_level 20 for use with ADC
  15. //            (reached level 13 of 20 on a 160x100 -a render)
  16. // ===============
  17.  
  18. #version 3.0
  19. global_settings { assumed_gamma 2.2 max_trace_level 20 }
  20.  
  21. #include "shapes.inc"
  22. #include "shapes2.inc"
  23. #include "colors.inc"
  24. #include "textures.inc"
  25.  
  26. #declare DMF_Hyperboloid = quadric {  /* Like Hyperboloid_Y, but more curvy */
  27.    <1.0, -1.0,  1.0>,
  28.    <0.0,  0.0,  0.0>,
  29.    <0.0,  0.0,  0.0>,
  30.    -0.5
  31. }
  32.  
  33. camera {
  34.    location <0.0, 28.0, -200.0>
  35.    direction <0.0, 0.0, 2.0>
  36.    up  <0.0, 1.0, 0.0>
  37.    right <4/3, 0.0, 0.0>
  38.    look_at <0.0, -12.0, 0.0>
  39. }
  40.  
  41. /* Light behind viewer postion (pseudo-ambient light) */
  42. light_source { <100.0, 500.0, -500.0> colour White }
  43.  
  44. union {
  45.    union {
  46.       intersection {
  47.          plane { y, 0.7 }
  48.          object { DMF_Hyperboloid scale <0.75, 1.25, 0.75> }
  49.          object { DMF_Hyperboloid scale <0.70, 1.25, 0.70> inverse }
  50.          plane { y, -1.0 inverse }
  51.       }
  52.       sphere { <0, 0, 0>, 1 scale <1.6, 0.75, 1.6 > translate <0, -1.15, 0> }
  53.  
  54.       scale <20, 25, 20>
  55.  
  56.       pigment {
  57.          Bright_Blue_Sky
  58.          turbulence 0.3
  59.          quick_color Blue
  60.          scale <8.0, 4.0, 4.0>
  61.          rotate 15*z
  62.       }
  63.       finish {
  64.          ambient 0.1
  65.          diffuse 0.75
  66.          phong 1
  67.          phong_size 100
  68.          reflection 0.35
  69.       }
  70.    }
  71.  
  72.    sphere {  /* Gold ridge around sphere portion of vase*/
  73.       <0, 0, 0>, 1
  74.       scale <1.6, 0.75, 1.6>
  75.       translate -7*y
  76.       scale <20.5, 4.0, 20.5>
  77.  
  78.       finish { Metal }
  79.       pigment { OldGold }
  80.    }
  81.  
  82.    bounded_by {
  83.       object {
  84.          Disk_Y
  85.          translate -0.5*y  // Remove for new Disk_Y definition
  86.          scale <34, 100, 34>
  87.       }
  88.    }
  89.  
  90. }
  91.  
  92. /* Stand for the vase */
  93. object { Hexagon
  94.    rotate -90.0*z             /* Stand it on end (vertical)*/
  95.    rotate -45*y               /* Turn it to a pleasing angle */
  96.    scale <40, 25, 40>
  97.    translate -70*y
  98.  
  99.    pigment {
  100.       Sapphire_Agate
  101.       quick_color Red
  102.       scale 10.0
  103.    }
  104.    finish {
  105.       ambient 0.2
  106.       diffuse 0.75
  107.       reflection 0.85
  108.    }
  109. }
  110.  
  111. union {
  112.    plane { z, 50  rotate -45*y }
  113.    plane { z, 50  rotate +45*y }
  114.  
  115.    pigment { DimGray }
  116.    finish {
  117.       ambient 0.2
  118.       diffuse 0.75
  119.       reflection 0.5
  120.    }
  121. }
  122.